Hallo Mase

Vielen Dank für die rasche Antwort. Ich habe mein Problem mit einem Array gelöst

Hier mein Code, ohne Screenupdatiing

Private Sub Workbook_Open()
' @Name:            Workbook_Open
' @Eigentümer:      gaw
' @Ersteller:       Roger Glanzmann
' @Version:         dev
' @Erstelldatum:    10.01.2022
' @Änderungsdatum:
'
' @Ablauf:          - Screenupdating ausschalten
'                   - liest den Namen der Datei aus
'                   - erstellt ein Mehrdimensionalesarray der Namen
'                     und auszublendenden Spalten aus dem Settingsblatt
'                   - erstellt ein Array der auszublendenden Spalten
'                   - vergleicht Dateiname mit Namen aus Array auf "enthält"
'                   - wenn Vergleich gleich true Spalten ausblenden
'                   - Screenupdating einschalten
'
' @Rückgabe:        keine Rückgabe
'

'
' Konstante deklarieren
Const cTBLSETTINGS = "tblSettings"          ' Tabellenname
Const cWSSETTINGS = "Settings"              ' Worksheetname
Const cWSMASTER = "Master"                  ' Worksheetname

'
' Variablen deklarieren
Dim wb              As Workbook     ' Objekt von diesem Workbook
Dim wsSettings      As Worksheet    ' Objekt von Blatt Settings
Dim wsMaster        As Worksheet    ' Objekt von Blatt Jahrestabelle
Dim wbName          As String       ' Dateiname
Dim arrDateiNamen   As Variant      ' Dateinamen aus tblSettings
Dim arrSpalten      As Variant      ' Spaltenbezeichnungen
Dim i               As Integer      ' Zähler für Schleifen
Dim i2              As Integer      ' zweiter Zähler für Schleifen
Dim iDateiNamen     As Integer      ' Anzahl der Dateinamen

'
' Objekte iniitieren
Set wb = ThisWorkbook                       ' Objekt von diesem Workbook initiiert
Set wsSettings = wb.Worksheets(cWSSETTINGS) ' Objekt von Worksheet Settings initiiert
Set wsMaster = wb.Worksheets(cWSMASTER)     ' Objekt von Worksheet Jahrestabelle initiiert

'
' Variablen iniitieren
wbName = wb.Name                                                    ' Worbookname
arrDateiNamen = wsSettings.ListObjects(cTBLSETTINGS).DataBodyRange  ' Array der tblSettings
iDateiNamen = wsSettings.ListObjects(cTBLSETTINGS).ListRows.Count   ' Anzahl der Zeilen von tblSettings

'
' Alle Spalten einblenden
wsMaster.Cells.EntireColumn.Hidden = False

'
' Durchsuchen der Dateinamen auf "enthält"
For i = 1 To iDateiNamen
    
    '
    ' Auf "enthält" Prüfen
    If InStr(wbName, arrDateiNamen(i, 1)) > 0 Then
    
        '
        ' restliche Ansichten konfigurieren
        arrSpalten = Split(arrDateiNamen(i, 2), ",")
        
        '
        ' Ausblende der Spalten
        For i2 = LBound(arrSpalten) To UBound(arrSpalten)
            wsMaster.Columns(arrSpalten(i2)).Hidden = True
        Next
    Else
    End If
Next
End Sub

Greetz Zeitplaner