Thema Datum  Von Nutzer Rating
Antwort
13.09.2023 15:49:04 Nouman
Solved
Blau VBA EXCEL Wiederholung von Formeln
 13.09.2023 16:44:27 Gast96865
NotSolved
06.10.2023 13:56:40 Bernd
NotSolved

Ansicht des Beitrags:
Von:
Gast96865		 Datum:
13.09.2023 16:44:27		 Views:
185		 Rating:
     
Antwort:
  Ja
Thema:
VBA EXCEL Wiederholung von Formeln

Range("Q36:Q36") ist eine umständliche Schreibweise von Range("Q36") - also von einer einzigen Zelle.

Deshalb ergibt deine Beschreibung bis jetzt keinerlei Sinn, da du keine Spalten ansprichst, sondern einzelne Zellen... und die Summe von einem einzigen Wert ist .... nunja, Sinnfrei.

Letztendlich läuft deine Frage jedoch in die Richtung von For-Schleifen.

Option Explicit

Sub Example()
  
  Dim wks As Excel.Worksheet
  Dim rngColumnData As Excel.Range
  Dim rngColumnTarget As Excel.Range
  
  Set wks = Worksheets("Tabelle1")
  
  Set rngColumnData = wks.Range("AQ2:AQ22")
  Set rngColumnTarget = wks.Range("AJ24")
  
  Dim i As Long
  For i = 1 To 5
    
    'Ausgabe in den Direktbereich
    Debug.Print rngColumnTarget.Address; " := AVERAGE("; rngColumnData.Address; ")"
    
    On Error Resume Next
    rngColumnTarget.Value = WorksheetFunction.Average(rngColumnData)
    If Err.Number Then rngColumnTarget.Value = CVErr(XlCVError.xlErrDiv0)
    On Error GoTo 0
    
    'den betrachteten Bereich eins nach rechts verschieben
    Set rngColumnData = rngColumnData.Offset(ColumnOffset:=1)
    'den betrachteten Bereich eins nach unten verschieben
    Set rngColumnTarget = rngColumnTarget.Offset(RowOffset:=1)
  Next
  
End Sub

Ausgabe im Direktbereich:

$AJ$24 := AVERAGE($AQ$2:$AQ$22)
$AJ$25 := AVERAGE($AR$2:$AR$22)
$AJ$26 := AVERAGE($AS$2:$AS$22)
$AJ$27 := AVERAGE($AT$2:$AT$22)
$AJ$28 := AVERAGE($AU$2:$AU$22)

 

Grüße

PS: SUM(X) / COUNT(X) ist auch bekannt als AVERAGE(X)     // arithmetischer Mittelwert

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
13.09.2023 15:49:04 Nouman
Solved
Blau VBA EXCEL Wiederholung von Formeln
 13.09.2023 16:44:27 Gast96865
NotSolved
06.10.2023 13:56:40 Bernd
NotSolved